StrictPolicy.idl

Go to the documentation of this file.

#ifndef _strict_policy_idl
#define _strict_policy_idl

/**
 * @file StrictPolicy.idl
 *
 * IDL file for the StrictPolicy sub-interface.
 */

#include "Broker.idl"

/**
 * Name space for subclasses of Broker::Policy.
 */
module BrokerPolicies
{
    /**
     * A simple strict priority-based contention policy.
     *
     * @sa StrictPolicyImpl
     */
    interface StrictPolicy : Broker::Policy
    {
        /**
         * Set the priority of a task.
         *
         * @param task The task whose priority should be changed.
         * @param priority The new priority.
         *
         * @exception CORBA::BAD_PARAM if task is nil.
         * @exception CORBA::BAD_PARAM if task is not managed by this policy.
         */
        void SetTaskPriority(in Broker::Task task, in short priority);
    
        /**
         * Get the priority of a task.
         *
         * @param task The task whose priority should be changed.
         * @return The task's priority.
         *
         * @exception CORBA::BAD_PARAM if task is nil.
         * @exception CORBA::BAD_PARAM if task is not managed by this policy.
         */
        short GetTaskPriority(in Broker::Task task);
    
        /**
         * @return The maximum percentage of CPU that can be allocated to all
         * of the tasks.
         */
        float GetMaxCPUAllocation();

        /**
         * @param amount The maximum percentage of CPU that can be allocated to
         * all of the tasks.
         */
        void SetMaxCPUAllocation(in float amount);

        /**
         * The minimum value that can be passed to SetMaxCPUAllocation.
         */
        const float CPU_ALLOCATION_MIN = 0.01;

        /**
         * The maximum value that can be passed to SetMaxCPUAllocation.
         */
        const float CPU_ALLOCATION_MAX = 0.99;
    };
};

#endif

---