;; Extend with letrec:
;;    letrec fact = proc(n) if n then *(n, (fact -(n,1))) else 1 
;;      in (fact 10)

;; An expval is (still)
;;   * a number
;;   * a proc
;;
;; A denval is an expval

;; Definition of proc:
(define-datatype
 proc proc?
 (closure (ids (list-of symbol?))
          (body-exp expression?)
          (env environment?)))

;;;;;;;; grammatical specification ;;;;;;;;;;;;;;;;

(define the-lexical-spec
  '((whitespace (whitespace) 
                skip)
    (id (letter (arbno (or letter digit "?")))
        make-symbol)
    (number ((or "" "-" "+") digit (arbno digit))
            make-number)))

(define the-grammar
  '((program (expression) a-program)

    (expression (number) lit-exp)
    (expression (id) var-exp)
    (expression
      (primitive "(" (separated-list expression ",") ")")
      primapp-exp)
    (expression ("let"
                 (arbno id "=" expression)
                 "in"
                 expression)
                let-exp)
    (expression ("letrec"
                 (arbno id "=" 
                        "proc" "(" (separated-list id ",") ")"
                        expression)
                 "in"
                 expression)
                letrec-exp)
    (expression ("proc"
                 "(" (separated-list id ",") ")"
                 expression)
                proc-exp)
    (expression ("(" expression (arbno expression) ")")
                app-exp)
    (expression ("if" expression
                 "then" expression
                 "else" expression)
                if-exp)
                 
    
    (primitive ("+")     add-prim)
    (primitive ("-")     subtract-prim)
    (primitive ("*")     mult-prim)
    (primitive ("add1")  incr-prim)
    (primitive ("sub1")  decr-prim)))

(sllgen:make-define-datatypes the-lexical-spec
                              the-grammar)

;;;;;;;;;;;;;;;; the interpreter ;;;;;;;;;;;;;;;;

; eval-program : program -> expval
;
; Evaluates the given program, using an environment that
;  binds i, v, and x to 1, 5, and 10, respectively.
;
;   (eval-program (a-program (lit-exp 0))) = 0
;   (eval-program (a-program (var-exp 'a))) = error
;   (eval-program (a-program (var-exp 'x))) = 10
;   (eval-program (a-program (primapp-exp
;                             (add-prim)
;                             (list (lit-exp 1)
;                                   (lit-exp 2))))) = 3
;
(define eval-program 
  (lambda (pgm)
    (cases program pgm
      (a-program (body)
        (eval-expression body (empty-env))))))

; eval-expression : expression env -> expval
;
; Evaluates an expression in the given environment.
;
;   (eval-expression (lit-exp 0)
;                     (empty-env)) = 0
;   (eval-expression (var-exp 'x)
;                     (empty-env)) = error
;   (eval-expression (var-exp 'x))
;                     (extend-env '(i v x) 
;                                 '(1 5 10)
;                                 (empty-env))) = 10
;   (eval-expression (primapp-exp
;                     (add-prim)
;                     (list (lit-exp 1)
;                           (lit-exp 2)))
;                    (empty-env)) = 3
;   (eval-expression (let-exp
;                     (list 'x 'y)
;                     (list (lit-exp 10) (lit-exp 7))
;                     (primapp-exp (add-prim)
;                                  (var-exp 'x)
;                                  (var-exp 'y))))) = 17
;
(define eval-expression 
  (lambda (exp env)
    (cases expression exp
      (lit-exp (datum) datum)
      (var-exp (id) (apply-env env id))
      (primapp-exp (prim rands)
        (let ((args (eval-rands rands env)))
          (apply-primitive prim args)))
      (let-exp (ids exps body-exp) 
               (eval-expression
                body-exp ;; expression
                (extend-env
                 ids ;; list-of-sym
                 (eval-rands exps env)
                 env)))
      (letrec-exp (ids arg-idss func-bodies body-exp)
                  (eval-expression
                   body-exp
                   (extend-env-recursively
                    ids ; list of sym
                    arg-idss
                    func-bodies
                    env)))
      ;; Handle proc evaluation.
      ;;  Essentially, we just return the proc (its
      ;;  variables and body), but we also remember the
      ;;  current environment, to implement lexical scoping.
      (proc-exp (ids body-exp)
                (closure ids
                         body-exp
                         env))
      ;; Handle application
      (app-exp (rator rands)
               (apply-proc
                (eval-expression rator env)
                (eval-rands rands env)))
      (if-exp (test then else)
              (if (zero? (eval-expression test env))
                  (eval-expression else env)
                  (eval-expression then env))))))

; apply-proc : expval list-of-expressions -> expval
(define (apply-proc func args)
  (cond
    [(number? func) (eopl:error 'apply-proc "not a func")]
    [(proc? func) (cases proc func
                         (closure (ids body-exp env)
                                  (eval-expression
                                   body-exp
                                   (extend-env
                                    ids
                                    args
                                    env))))]))


; eval-rands : list-of-expression env -> list-of-expval
(define eval-rands
  (lambda (rands env)
    (map (lambda (x) (eval-rand x env)) rands)))

; eval-rand : expression env -> expval
(define eval-rand
  (lambda (rand env)
    (eval-expression rand env)))

; apply-primitive : primitive list-of-expval -> expval
;  (apply-prim (add-prim) '(0 3)) = 3
;  (apply-prim (sub-prim) '(1 2)) = -1
(define apply-primitive
  (lambda (prim args)
    (cases primitive prim
      (add-prim  () (+ (car args) (cadr args)))
      (subtract-prim () (- (car args) (cadr args)))
      (mult-prim  () (* (car args) (cadr args)))
      (incr-prim  () (+ (car args) 1))
      (decr-prim  () (- (car args) 1)))))

;;;;;;;;;;;;;;;; environments ;;;;;;;;;;;;;;;;

;; Abstract envrionment datatype implemenation.

(define-datatype environment environment?
  (empty-env-record)
  (extended-env-record
    (syms (list-of symbol?))
    (vec vector?)
    (env environment?))
  ;; last case no longer used with the 
  ;; second `extend-env-recursively':
  (recursively-extended-env-record
   (func-ids (list-of symbol?))
   (arg-idss (list-of (list-of symbol?)))
   (func-exps (list-of expression?))
   (old-env environment?)))

; empty-env : -> env
(define empty-env
  (lambda ()
    (empty-env-record)))

; extend-env : list-of-sym list-of-denval env -> env 
(define extend-env
  (lambda (syms vals env)
    (extended-env-record syms (list->vector vals) env)))

; extend-env-recursively : list-of-symbols list-of-list-of-symbols
;                          list-of-expression environment
;; Original implementation:
;(define (extend-env-recursively names idss bodies env)
;  (recursively-extended-env-record names
;                                   idss
;                                   bodies
;                                   env))

; New implementation, with a fix-up for a temporarily broken environment:
(define (extend-env-recursively names idss bodies env)
  (let ([new-env (extend-env names (make-zeros names) env)])
    (let ([closures (make-closures idss bodies new-env)])
      (begin
        (cases environment new-env
               (extended-env-record (names vec old-env)
                                    (fixup-vector! vec 0 closures))
               (empty-env-record () 'impossible)
               (recursively-extended-env-record (_ __ ___ ____)
                                         'impossble))
      new-env))))

;; make-zeros: list-of-sym ->list-of-num
(define (make-zeros l)
  (map (lambda (x) 0) l))

(define (make-closures idss bodies env)
  (map (lambda (ids body) (closure ids body env))
       idss
       bodies))


(define (fixup-vector! vec pos closures)
  (cond
    [(null? closures) vec]
    [else (begin
            (vector-set! vec pos (car closures))
            (fixup-vector! vec (+ pos 1) (cdr closures)))]))

; apply-env : env sym -> denval
(define apply-env
  (lambda (env sym)
    (cases environment env
      (empty-env-record ()
        (eopl:error 'apply-env "No binding for ~s" sym))
      (extended-env-record (syms vals env)
        (let ((position (env-find-position sym syms)))
          (if (number? position)
              (vector-ref vals position)
              (apply-env env sym))))
      (recursively-extended-env-record 
       (func-ids arg-idss bodies old-env)
       (let ((position (env-find-position sym func-ids)))
         (if (number? position)
             (closure
              (list-ref arg-idss position)
              (list-ref bodies position)
              env)
             (apply-env old-env sym)))))))
       

;; Environment helper functions

; env-find-position : sym list-of-symbols -> num-or-#f
(define env-find-position 
  (lambda (sym los)
    (list-find-position sym los)))

; list-find-position : sym list-of-symbols -> num-or-#f
(define list-find-position
  (lambda (sym los)
    (list-index (lambda (sym1) (eqv? sym1 sym)) los)))

; list-index : pred list-of-symbols -> num-or-#f
(define list-index
  (lambda (pred ls)
    (cond
      ((null? ls) #f)
      ((pred (car ls)) 0)
      (else (let ((list-index-r 
                   (list-index pred (cdr ls))))
              (if (number? list-index-r)
                (+ list-index-r 1)
                #f))))))

;;;;;;;;;;;;;;;; top level ;;;;;;;;;;;;;;;;

; read-eval-print : -> [loops forever]
(define read-eval-print
  (lambda ()
    ((sllgen:make-rep-loop "-->"
                           eval-program
                           (sllgen:make-stream-parser
                            the-lexical-spec
                            the-grammar)))))