;; Interpreter for language with let and proc.

;; An expval is
;;   * a number
;;   * a proc
;;
;; A denval is an expval

(define-datatype
 proc proc?
 (closure (ids (list-of symbol?))
          (body-exp expression?)
          (env environment?)))

(define-datatype
 cproc cproc?
 (cclosure (body-exp cexpression?)
           (env environment?)))

;;;;;;;; grammatical specification ;;;;;;;;;;;;;;;;

(define the-lexical-spec
  '((whitespace (whitespace) 
                skip)
    (id (letter (arbno (or letter digit "?")))
        make-symbol)
    (number ((or "" "-" "+") digit (arbno digit))
            make-number)))

(define the-grammar
  '((program (expression) a-program)

    (expression (number) lit-exp)
    (expression (id) var-exp)
    (expression
      (primitive "(" (separated-list expression ",") ")")
      primapp-exp)
    (expression ("let"
                 (arbno id "=" expression)
                 "in"
                 expression)
                let-exp)
    (expression ("proc"
                 "(" (separated-list id ",") ")"
                 expression)
                proc-exp)
    (expression ("(" expression (arbno expression) ")")
                app-exp)
    (expression ("if" expression
                 "then" expression
                 "else" expression)
                if-exp)
                 
    
    (primitive ("+")     add-prim)
    (primitive ("-")     subtract-prim)
    (primitive ("*")     mult-prim)
    (primitive ("add1")  incr-prim)
    (primitive ("sub1")  decr-prim)))

(sllgen:make-define-datatypes the-lexical-spec
                              the-grammar)

(define-datatype cexpression cexpression?
   (lit-cexp (n number?))
   (var-cexp (frame-index number?)
             (position-in-frame number?))
   (primapp-cexp (prim primitive?)
                 (rands (list-of cexpression?)))
   (let-cexp (rands (list-of cexpression?))
             (body cexpression?))
   (proc-cexp (body cexpression?))
   (app-cexp (rator cexpression?)
             (rands (list-of cexpression?)))
   (if-cexp (test cexpression?)
            (then cexpression?)
            (else cexpression?)))


;;;;;;;;;;;;;;;; the interpreter ;;;;;;;;;;;;;;;;
;;;;;;;;;;; for the original language ;;;;;;;;;;;

; eval-program : program -> expval
(define eval-program 
  (lambda (pgm)
    (cases program pgm
      (a-program (body)
        (eval-expression body (empty-env))))))

; eval-expression : expression env -> expval
(define eval-expression 
  (lambda (exp env)
    (cases expression exp
      (lit-exp (datum) datum)
      (var-exp (id) (apply-env env id))
      (primapp-exp (prim rands)
        (let ((args (eval-rands rands env)))
          (apply-primitive prim args)))
      (let-exp (ids exps body-exp) 
               (eval-expression
                body-exp ;; expression
                (extend-env
                 ids ;; list-of-sym
                 (eval-rands exps env)
                 env)))
      (proc-exp (ids body-exp)
                (closure ids
                         body-exp
                         env))
      (app-exp (rator rands)
               (apply-proc
                (eval-expression rator env)
                (eval-rands rands env)))
      (if-exp (test then else)
              (if (zero? (eval-expression test env))
                  (eval-expression else env)
                  (eval-expression then env))))))

; apply-proc : expval list-of-expressions -> expval
(define (apply-proc func args)
  (cond
    [(number? func) (eopl:error 'apply-proc "not a func")]
    [(proc? func) (cases proc func
                         (closure (ids body-exp env)
                                  (eval-expression
                                   body-exp
                                   (extend-env
                                    ids
                                    args
                                    env))))]))


; eval-rands : list-of-expression env -> list-of-expval
(define eval-rands
  (lambda (rands env)
    (map (lambda (x) (eval-rand x env)) rands)))

; eval-rand : expression env -> expval
(define eval-rand
  (lambda (rand env)
    (eval-expression rand env)))

; apply-primitive : primitive list-of-expval -> expval
;  (apply-prim (add-prim) '(0 3)) = 3
;  (apply-prim (sub-prim) '(1 2)) = -1
(define apply-primitive
  (lambda (prim args)
    (cases primitive prim
      (add-prim  () (+ (car args) (cadr args)))
      (subtract-prim () (- (car args) (cadr args)))
      (mult-prim  () (* (car args) (cadr args)))
      (incr-prim  () (+ (car args) 1))
      (decr-prim  () (- (car args) 1)))))

;;;;;;;;;;;;;;;;;;;; compiler ;;;;;;;;;;;;;;;;;;;;

(define-datatype cprogram cprogram?
    (a-cprogram (expr cexpression?)))

; compile-program : program -> cprogram
(define compile-program 
  (lambda (pgm)
    (cases program pgm
      (a-program (body)                 
                 (a-cprogram
                  (compile-expression body (empty-env)))))))

; compile-expression : expression env -> cexpression
(define compile-expression 
  (lambda (exp env)
    (cases expression exp
      (lit-exp (datum) (lit-cexp datum))
      (var-exp (id) (lexical-position-in-env env id))
      (primapp-exp (prim rands)
        (let ((crands (compile-rands rands env)))
          (primapp-cexp prim crands)))
      (let-exp (ids exps body-exp) 
               (let ([cexps (compile-rands exps env)])
                 (let ([cbody-exp (compile-expression 
                                   body-exp 
                                   (extend-env
                                    ids
                                    ids
                                    env))])
                   (let-cexp cexps cbody-exp))))
      (proc-exp (ids body-exp)
                (let ([cbody-exp (compile-expression
                                  body-exp
                                  (extend-env
                                   ids
                                   ids
                                   env))])
                  (proc-cexp cbody-exp)))
      (app-exp (rator rands)
               (app-cexp
                (compile-expression rator env)
                (compile-rands rands env)))
      (if-exp (test then else)
              (if-cexp (compile-expression test env)
                       (compile-expression then env)
                       (compile-expression else env))))))

(define (compile-rands rands env)
  (map (lambda (rand)
         (compile-expression rand env))
       rands))

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; new interpreter

; eval-cprogram : cprogram -> expval
(define eval-cprogram 
  (lambda (pgm)
    (cases cprogram pgm
      (a-cprogram (body)
        (eval-cexpression body (empty-env))))))

; eval-cexpression : cexpression env -> expval
(define eval-cexpression 
  (lambda (exp env)
    (cases cexpression exp
      (lit-cexp (datum) datum)
      (var-cexp (frame pos) (apply-lexical-address-to-env env frame pos))
      (primapp-cexp (prim rands)
        (let ((args (eval-crands rands env)))
          (apply-primitive prim args)))
      (let-cexp (exps body-exp) 
                (eval-cexpression
                 body-exp ;; expression
                 (extend-env
                  (map (lambda (x) 'dont-care) exps) ;; list-of-sym
                  (eval-crands exps env)
                  env)))
      (proc-cexp (body-exp)
                 (cclosure body-exp
                           env))
      (app-cexp (rator rands)
                (apply-proc
                 (eval-cexpression rator env)
                 (eval-crands rands env)))
      (if-cexp (test then else)
               (if (zero? (eval-cexpression test env))
                   (eval-cexpression else env)
                   (eval-cexpression then env))))))

; apply-proc : expval list-of-cexpressions -> expval
(define (apply-proc func args)
  (cond
    [(number? func) (eopl:error 'apply-proc "not a func")]
    [(cproc? func) (cases cproc func
                          (cclosure (body-exp env)
                                    (eval-cexpression
                                     body-exp
                                     (extend-env
                                      (map (lambda (x) 'dont-care) args)
                                      args
                                      env))))]))


; eval-crands : list-of-cexpression env -> list-of-expval
(define eval-crands
  (lambda (rands env)
    (map (lambda (x) (eval-cexpression x env)) rands)))

;;;;;;;;;;;;;;;; environments ;;;;;;;;;;;;;;;;

;; Abstract envrionment datatype implemenation.

(define-datatype environment environment?
  (empty-env-record)
  (extended-env-record
    (syms (list-of symbol?))
    (vec vector?)
    (env environment?)))

; empty-env : -> env
(define empty-env
  (lambda ()
    (empty-env-record)))

; extend-env : list-of-sym list-of-denval env -> env 
(define extend-env
  (lambda (syms vals env)
    (extended-env-record syms (list->vector vals) env)))

; apply-env : env sym -> denval
(define apply-env
  (lambda (env sym)
    (cases environment env
      (empty-env-record ()
        (eopl:error 'apply-env "No binding for ~s" sym))
      (extended-env-record (syms vals env)
        (let ((position (env-find-position sym syms)))
          (if (number? position)
              (vector-ref vals position)
              (apply-env env sym)))))))

; apply-lexical-address-to-env : env frame pos -> denval
(define apply-lexical-address-to-env
  (lambda (env frame pos)
    (cases environment env
      (empty-env-record ()
        (eopl:error 'apply-lex-pos-env "No more frames"))
      (extended-env-record (syms vals env)
        (if (zero? frame)
            (vector-ref vals pos)
            (apply-lexical-address-to-env
             env
             (- frame 1)
             pos))))))

; lexical-position-in-env : env sym -> cexp
(define lexical-position-in-env
  (lambda (env sym)
    (cases environment env
      (empty-env-record ()
        (eopl:error 'lex-pos-in-env "No binding for ~s" sym))
      (extended-env-record (syms vals env)
        (let ((position (env-find-position sym syms)))
          (if (number? position)
              (var-cexp 0 position)
              (cases cexpression (lexical-position-in-env env sym)
                     (var-cexp (frame pos)
                               (var-cexp (+ frame 1) pos))
                     (else 'impossible))))))))

;; Environment helper functions

; env-find-position : sym list-of-symbols -> num-or-#f
(define env-find-position 
  (lambda (sym los)
    (list-find-position sym los)))

; list-find-position : sym list-of-symbols -> num-or-#f
(define list-find-position
  (lambda (sym los)
    (list-index (lambda (sym1) (eqv? sym1 sym)) los)))

; list-index : pred list-of-symbols -> num-or-#f
(define list-index
  (lambda (pred ls)
    (cond
      ((null? ls) #f)
      ((pred (car ls)) 0)
      (else (let ((list-index-r 
                   (list-index pred (cdr ls))))
              (if (number? list-index-r)
                (+ list-index-r 1)
                #f))))))

;;;;;;;;;;;;;;;; top level ;;;;;;;;;;;;;;;;

; read-eval-print : -> [loops forever]
(define read-eval-print
  (lambda ()
    ((sllgen:make-rep-loop "-->"
                           eval-program
                           (sllgen:make-stream-parser
                            the-lexical-spec
                            the-grammar)))))

; read-compile-print : -> [loops forever]
(define read-compile-print
  (lambda ()
    ((sllgen:make-rep-loop "-->"
                           compile-program
                           (sllgen:make-stream-parser
                            the-lexical-spec
                            the-grammar)))))

; read-compile-eval-print : -> [loops forever]
(define read-compile-eval-print
  (lambda ()
    ((sllgen:make-rep-loop "-->"
                           (lambda (p)
                             (eval-cprogram (compile-program p)))
                           (sllgen:make-stream-parser
                            the-lexical-spec
                            the-grammar)))))