################################################################
# Startup script for basic Cadence. This does NOT set up specific NCSU
# or AMI or TSMC things.  For those, you need to set things up on your own...  
# Erik Brunvand, University of Utah
# 
echo Using the setup-cadence script from F08
##################################################################
# Set the base directory for the cadence software
setenv base_dir "/uusoc/facility/cad_tools/Cadence"
##################################################################

# Set some configuration environment variables. 
setenv CLS_CDSD_COMPATIBILITY_LOCKING NO
setenv CDS_Netlisting_Mode "Analog"
setenv SPECTRE_DEFAULTS -E
setenv CDS_LOAD_ENV CWDElseHome
setenv SKIP_CDS_DIALOG
set uname = "/bin/uname"

# Point to each of the installation directories for the tool suites
setenv CDS   $base_dir/IC-F08     # Basic Cadence (i.e. IC tools)
setenv IC    $base_dir/IC-F08     # IC tools (composer, virtuoso, etc.)
setenv ICC   $base_dir/ICC-F08    # ICC (ccar) tools
setenv SOC   $base_dir/SOC-F08    # SOC Encounter place and route
setenv RC    $base_dir/RC-F08     # RTL Compiler synthesis
setenv MMSIM $base_dir/MMSIM-F07  # Spectre analog simulation
setenv IUS   $base_dir/IUS-F08    # Verilog simulators
setenv ETS   $base_dir/ETS-F08    # Encounter Library Characterizer
setenv ASSURAHOME $base_dir/ASSURA-F07-5141 # ASSURA DRC

# Set some environment variables for licensing
# Note - make a file named common_license in the main Cadence
# installation directory that contains the following two lines: 
#    SERVER <servername> <hostid> <port> 
#    USE_SERVER
# (port is usually 5280, but look in your license file)
setenv CDS_INST_DIR $IC
setenv CDS_LIC_FILE $base_dir/common_license
setenv CDS_LIC_TIMEOUT 30
setenv TERM $term
setenv LANG C

# some handy path aliases
alias prepend 'if (-d \!:2) if ("$\!:1" \!~ *"\!:2"*) setenv \!:1 "\!:2":${\!:1}'
alias extend  'if (-d \!:2) if ("$\!:1" \!~ *"\!:2"*) setenv \!:1 ${\!:1}:\!:2'

# update the shell's path to point to the tools
prepend PATH $ETS/bin 
prepend PATH $RC/tools/bin
prepend PATH $SOC/tools/bin
prepend PATH $ASSURAHOME/tools/bin
prepend PATH $ASSURAHOME/tools/assura/bin
prepend PATH $ICC/tools/bin
prepend PATH $ICC/tools/iccraft/bin
prepend PATH $ICC/tools/DFII/bin
prepend PATH $IUS/tools/bin
prepend PATH $IC/tools/DFII/bin
prepend PATH $IC/tools/bin
prepend PATH $MMSIM/tools/bin
prepend PATH $MMSIM/tools/DFII/bin

if ( $?MANPATH ) then 
extend MANPATH $IC/share/man
extend MANPATH $IC/tools/man
else
setenv MANPATH $IC/share/man
extend MANPATH $IC/tools/man
endif

if ( $?LD_LIBRARY_PATH ) then 
  prepend LD_LIBRARY_PATH $ASSURAHOME/tools/lib
  prepend LD_LIBRARY_PATH $ASSURAHOME/tools/assura/lib
  prepend LD_LIBRARY_PATH $IUS/tools/lib
  prepend LD_LIBRARY_PATH $IC/tools/lib
else 
  setenv LD_LIBRARY_PATH $ASSURAHOME/tools/lib
  prepend LD_LIBRARY_PATH $ASSURAHOME/tools/assura/lib
  prepend LD_LIBRARY_PATH $IUS/tools/lib
  prepend LD_LIBRARY_PATH $IC/tools/lib
endif

# add a fix for ICC tools under Solaris 9 
limit descriptors 1024
limit -h descriptors 1024

# if the user has LOCAL_CADSETUP defined so that local modifications
# to the .cdsinit and .cdsenv are enabled, then make sure 
# Cadence knows about it... 
if ($?LOCAL_CADSETUP) then
   echo "Setting up local mods from" $LOCAL_CADSETUP
   echo "for the .simrc and .cdsplotinit files... " 
   setenv SIMRC $LOCAL_CADSETUP/cadence
   setenv CDSPLOTINIT $LOCAL_CADSETUP/cadence
endif

# If you've already set up the NCSU enhancements, don't bother
# with this message... 
if (! $?NCSU_LOCATION) then 
  echo "You are now set up to run cadence tools (icfb, encounter, "
  echo "nc_verilog, etc.) but this script did NOT set you up to run" 
  echo "with any particular design kit. If you have a particular" 
  echo "design kit you'd like to use (ami, NCSU, IBM, etc.), you" 
  echo "need to set that up on your own using your own Cadence setup files." 
  echo " "
endif

# You're now ready to execute the Cadence tools!